     A                                      DSPSIZ(24 80 *DS3)
     A                                      INDARA
     A          R SFL                       SFL
     A            OPT            1   B  6  3
     A            NUM            7  0O  6  6
     A            NAME          25   O  6 14
     A            KWD           40   O  6 40
     A          R CTL                       SFLCTL(SFL)
     A                                      CA03(03)
     A                                      OVERLAY
     A                                      PRINT
     A  51                                  SFLDSP
     A N50                                  SFLDSPCTL
     A  50                                  SFLCLR
     A N50                                  SFLEND(*MORE)
     A                                      SFLSIZ(9999)
     A                                      SFLPAG(0015)
     A                                  1 26'Approved Vendor Keyword Search'
     A                                      DSPATR(HI)
     A                                  3  2'Keywords containing:'
     A            SEARCH        40   B  3 23DSPATR(HI)
     A                                  5  2'Opt'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  5  6' Vendor'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  5 14'Vendor Name              '
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  5 40'Keyword                           -
     A                                            '
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A          R FOOTER
     A                                 24  2'F3=Exit' 