     A                                      DSPSIZ(24 80 *DS3)
     A                                      INDARA
     A                                      PRINT
     A          R CLAIMSFL                  SFL
     A                                      TEXT('Claims Subfile')
     A            OPTION         1A  B 11  3VALUES(' ' '2' '4' '5')
     A            CMDESC        25A  O 11 17
     A            S1NUMBER       9S 0O 11  6
     A            CMMDY          6Y 0O 11 44EDTCDE(Y)
     A            CMCOUNTY      20A  O 11 54
     A          R CLAIMCTL                  SFLCTL(CLAIMSFL)
     A                                      TEXT('View Claims')
     A                                      CA03(03 'Exit')
     A                                      CA05(05 'Refresh')
     A                                      CF06(06 'Add')
     A                                      OVERLAY
     A N70                                  SFLDSP
     A N70                                  SFLDSPCTL
     A  70                                  SFLCLR
     A N70                                  SFLEND(*MORE)
     A                                      SFLSIZ(0100)
     A                                      SFLPAG(0010)
     A                                  1 28'Maintain Claims/Accidents'
     A                                      DSPATR(HI)
     A                                 10  6'Claim'
     A                                      DSPATR(HI)
     A                                 10 17'Description'
     A                                      DSPATR(HI)
     A                                 10  2'Opt'
     A                                      DSPATR(HI)
     A                                 10 45'Date'
     A                                      DSPATR(HI)
     A                                  8  3'2=Change'
     A                                      COLOR(BLU)
     A                                  8 14'4=Delete'
     A                                      COLOR(BLU)
     A                                  8 25'5=Display'
     A                                      COLOR(BLU)
     A                                 10 54'County'
     A                                      DSPATR(HI)
     A            C1NUMBER       9Y 0B  4 28EDTCDE(Z)
     A            C1DESC        25A  B  6 28
     A                                  4  3'Position by Claim #:'
     A                                  6  3'Position by Description:'
     A          R DETAIL
     A                                      TEXT('Claim Details')
     A                                      CA03(03 'Exit')
     A                                      CF06(06 'Damages')
     A                                      CF07(07 'Work Orders')
     A                                      CF08(08 'Injured')
     A                                      CF09(09 'Policies')
     A                                      CF10(10 'Towing')
     A                                      CF11(11 'Notes')
     A                                      CA12(12 'Cancel')
     A                                      CF14(14 'Photos')
     A                                      CF15(15 'Documents')
     A                                  1 32'Accident/Claim Detail'
     A                                      DSPATR(HI)
     A                                  4  3'Claim Number:'
     A                                      DSPATR(HI)
     A                                 21 16'F6=Damages'
     A                                      COLOR(BLU)
     A                                 22 29'F12=Cancel'
     A                                      COLOR(BLU)
     A                                  5  3'Description:'
     A                                  6  3'Date:'
     A                                  7  3'Time:'
     A                                  8  3'Units Involved:'
     A                                  9  3'Injured:'
     A                                 10  3'Hit and run?'
     A                                 11  3'Completed?'
     A                                 14 20'Estimates'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 15  3'Your Equipment:'
     A                                 16  3'Other Equipment:'
     A                                 17  3'Property:'
     A                                 18  3'Total:'
     A                                 14 33'Costs'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  5 47'Accident Location'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  6 47'County:'
     A                                  7 47'Address:'
     A                                  9 47'City:'
     A                                 10 47'State:'
     A                                 11 47'Zip:'
     A                                 12  3'Accident Type:'
     A                                 21 29'F7=Work Orders'
     A                                      COLOR(BLU)
     A                                 21 46'F8=Injured'
     A                                      COLOR(BLU)
     A                                 21 59'F9=Police'
     A                                      COLOR(BLU)
     A                                 22 16'F11=Notes'
     A                                      COLOR(BLU)
     A                                 22  3'F10=Towing'
     A                                      COLOR(BLU)
     A                                 21  3'F3=Exit'
     A                                      COLOR(BLU)
     A                                 22 46'F14=Photos'
     A                                      COLOR(BLU)
     A                                 22 59'F15=Documents'
     A                                      COLOR(BLU)
     A                                 14 47'Classification'
     A                                      DSPATR(UL)
     A                                      DSPATR(HI)
     A                                 15 47'Motorcycle involved?'
     A                                 16 47'Flat tire?'
     A                                 17 47'Broken windshield?'
     A                                 18 47'Vandalism?'
     A                                 19 47'Pedestrian involved?'
     A            CMMOTOR        1A  B 15 68
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMFLATTIRE     1A  B 16 68
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMVANDAL       1A  B 18 68
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMBROKENW      1A  B 17 68
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMPEDESTR      1A  B 19 68
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMNUMBER       9S 0O  4 20
     A            CMMDY          6Y 0B  6 20EDTCDE(Y)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMDESC        25A  B  5 20
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMTIME         6Y 0B  7 20EDTWRD('  :  :  ')
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMHITRUN       1A  B 10 20
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A                                 10 22'(Y/N)'
     A  80                                  DSPATR(ND)
     A            CMCOMPLETE     1A  B 11 20
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A                                 11 22'(Y/N)'
     A  80                                  DSPATR(ND)
     A            CMUNITS        3S 0B  8 20
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMINJURED      3S 0B  9 20
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMACTYPE       3A  B 12 20
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A                                 12 24'(?=Prompt)'
     A  80                                  DSPATR(ND)
     A            CMADDR2       25A  B  8 56
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMADDR1       25A  B  7 56
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMCITY        20A  B  9 56
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMSTATE        2A  B 10 56
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A                                 10 59'(?=Prompt)'
     A  80                                  DSPATR(ND)
     A            CMZIP          5Y 0B 11 56EDTCDE(Z)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMCOUNTY      20A  B  6 56
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMEQEST        7Y 2B 15 20EDTCDE(3)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMOTHEST       7Y 2B 16 20EDTCDE(3)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMPROPEST      7Y 2B 17 20EDTCDE(3)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMTOTEST       7Y 2O 18 20EDTCDE(3)
     A            CMEQCOST       7Y 2B 15 33EDTCDE(3)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMOTHCOST      7Y 2B 16 33EDTCDE(3)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMPROPCOST     7Y 2B 17 33EDTCDE(3)
     A  80                                  DSPATR(PR)
     A N80                                  DSPATR(UL)
     A            CMTOTCOST      7Y 2O 18 33EDTCDE(3)
     A                                 16 70'(Y/N)'
     A  80                                  DSPATR(ND)
     A                                 15 70'(Y/N)'
     A  80                                  DSPATR(ND)
     A                                 17 70'(Y/N)'
     A  80                                  DSPATR(ND)
     A                                 18 70'(Y/N)'
     A  80                                  DSPATR(ND)
     A                                 19 70'(Y/N)'
     A  80                                  DSPATR(ND)
     A            MESSAGE       10A  O  1 70DSPATR(HI)
     A          R BOTTOM
     A                                      TEXT('Function Keys')
     A                                      CA03(03 'Exit')
     A                                      CA05(05 'Refresh')
     A                                      CF06(06 'Add')
     A                                      OVERLAY
     A                                 23  3'F3=Exit'
     A                                      COLOR(BLU)
     A                                 23 13'F5=Refresh'
     A                                      COLOR(BLU)
     A                                 23 26'F6=Add'
     A                                      COLOR(BLU)
     A          R CONFIRMDEL
     A                                      TEXT('Delete Claim Confirm Screen')
     A                                      CA12(12 'Cancel')
     A                                  1  3'Delete Accident/Claim'
     A                                      DSPATR(HI)
     A                                  4  3'Claim Number:'
     A                                      DSPATR(HI)
     A                                  9 19'F12=Cancel'
     A                                      COLOR(BLU)
     A                                  6  3'Description:'
     A                                      DSPATR(HI)
     A                                  9  3'Enter=Confirm'
     A                                      COLOR(BLU)
     A            CMNUMBER       9S 0O  4 17
     A            CMDESC        25A  O  6 17 