     A                                      DSPSIZ(24 80 *DS3)
     A                                      INDARA
     A          R SFL                       SFL
     A            OPT            1A  B  5 10
     A            CUSTNO         5Y 0O  5 12EDTCDE(Z)
     A            NAME          30A  O  5 18
     A            CITY          20A  O  5 49
     A            STATE          2A  O  5 70
     A          R CTL                       SFLCTL(SFL)
     A                                      CA03(03 'F3=Exit')
     A                                      CA10(10 'F10=Add')
     A                                      OVERLAY
     A  51                                  SFLDSP
     A N50                                  SFLDSPCTL
     A  50                                  SFLCLR
     A N50                                  SFLEND(*MORE)
     A                                      SFLSIZ(9999)
     A                                      SFLPAG(0017)
     A                                  4 12' Cust'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  4 18'    Customer Name             '
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  4 49'    City            '
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  4 70'ST'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  1 31'Customer Maintenance'
     A                                      DSPATR(HI)
     A                                  4  8'Opt'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  2  8'1=Select'
     A                                      COLOR(BLU)
     A          R FTR
     A                                 24  2'F3=Exit'
     A            MSG           78   O 23  2DSPATR(HI)
     A                                      DSPATR(BL)
     A                                 24 12'F10=Add New'
     A          R MAINT
     A                                      CHGINPDFT
     A                                      CA03(03 'F3=Exit')
     A                                      CA12(12 'F12=Cancel')
     A                                  1 31'Customer Maintenance'
     A                                      DSPATR(HI)
     A                                  3  2'Cust no:'
     A            CUSTNO         5Y 0O  3 11EDTCDE(Z)
     A                                  5  5'Name:'
     A            NAME          30A  B  5 11
     A N40                                  DSPATR(UL)
     A  40                                  DSPATR(PR)
     A                                      CHECK(LC)
     A                                  6  3'Street:'
     A            STREET        30A  B  6 11
     A N40                                  DSPATR(UL)
     A  40                                  DSPATR(PR)
     A                                      CHECK(LC)
     A                                  7  5'City:'
     A            CITY          20A  B  7 11
     A N40                                  DSPATR(UL)
     A  40                                  DSPATR(PR)
     A                                      CHECK(LC)
     A                                  8  4'State:'
     A            STATE          2A  B  8 11
     A N40                                  DSPATR(UL)
     A  40                                  DSPATR(PR)
     A                                  9  3'Postal:'
     A            POSTAL        10A  B  9 11
     A N40                                  DSPATR(UL)
     A  40                                  DSPATR(PR)
     A                                      CHECK(LC)
     A            MSG           78A  O 23  2DSPATR(HI)
     A                                      DSPATR(BL)
     A                                 24  2'F3=Exit'
     A                                 24 14'F12=Cancel'
     A                                 24 70'ENTER=Save'
     A          R SIGNIN
     A                                      CA03(03 'F3=Exit')
     A                                  3  2'Please enter your user-id and pass-
     A                                      word for'
     A                                      DSPATR(HI)
     A            REALM         78   O  4  2DSPATR(HI)
     A                                  9  2'User Id:'
     A            USERID        10A  B  9 12CHECK(LC)
     A                                 11  2'Password:'
     A            PASSWORD      20A  B 11 12CHECK(LC)
     A                                      DSPATR(ND)
     A                                 24  2'F3=Exit'
     A                                      COLOR(BLU) 
